PPT 无法保存为高清图片的解决方法？

解决方法如下（来自微软官方帮助文档）：
https://learn.microsoft.com/en-us/office/troubleshoot/powerpoint/change-export-slide-resolution

不过是全英文，我简单翻译一下。

打开注册表编辑器。开始-运行-regedit，或者在 Windows 10 中直接搜索注册表。

进入注册表目录：
HKEY_CURRENT_USER\Software\Microsoft\Office\XX.0\PowerPoint\Options

(XX 值对应你的 PowerPoint 版本，2003版对应11，2007版是12，2010版是14，2013版是15，2016版之后是16 )

比如 Office2016 的话，对应目录为：

HKEY_CURRENT_USER\Software\Microsoft\Office\16.0\PowerPoint\Options

Windows 10 新版可以在地址栏直接输入，但早期版本的 Win10 和更早的 Win7 得自己一层一层翻。

在 Options 目录里右键新建一个 DWORD (32位)值名为 ExportBitmapResolution，选择十进制然后填入你要设定的分辨率，一般建议填入300。

在默认幻灯片尺寸下，300dpi对应的输出图片尺寸为3000x2250，绝大部分使用完全够了。

注意：Office 2010及以下版本有限制最高只能设定为307，同时输出图像长边也限制为 3072 像素。2013及以上版本，最高可以设置1000多。具体见：
https://learn.microsoft.com/en-us/office/troubleshoot/powerpoint/change-export-slide-resolution#limitations

实际上，300足够日常使用，常见打印机的打印分辨率也是300dpi左右。如果是Office2013以上版本，最高建议600dpi，dpi过高可能会使文件偏大用起来反而不方便。

最后记得重启PPT，再重新导出为JPG图片。

楼上正解！不过对于电脑小白操作起来有点繁琐，我把它写成了一条命令：
reg add HKCU\Software\Microsoft\Office\16.0\PowerPoint\Options /v "ExportBitmapResolution" /t "REG_DWORD" /d 300 /f

命令中加粗部分的16.0表示Office版本，300表示dpi。

操作方法：以管理员身份运行CMD，执行上述命令即可。

直接写成了 bat 批处理程序：
mode con cols=50 lines=23
@echo --------------------------------------------
@echo. 
@echo              PPT_DPI设置工具 
@echo.        
@echo    功能: 设置PowerPoint保存图片的分辨率    
@echo.
@echo --------------------------------------------

@reg query "HKEY_CLASSES_ROOT\PowerPoint.Application\CurVer" > temp_setdpi.txt
@echo off
 
type temp_setdpi.txt | find "PowerPoint.Application.11" > NUL && goto office2003
type temp_setdpi.txt | find "PowerPoint.Application.12" > NUL && goto office2007
type temp_setdpi.txt | find "PowerPoint.Application.14" > NUL && goto office2010
type temp_setdpi.txt | find "PowerPoint.Application.15" > NUL && goto office2013
type temp_setdpi.txt | find "PowerPoint.Application.16" > NUL && goto office2016

goto office_null
 
:office2003
@echo     检测到您的PowerPoint版本为2003
set version=11
goto office_old

:office2007
@echo     检测到您的PowerPoint版本为2007
set version=12
goto office_old

:office2010
@echo     检测到您的PowerPoint版本为2010
set version=14
goto office_old

:office2013
@echo     检测到您的PowerPoint版本为2013
set version=15
goto office_old

:office2016
@echo     检测到您的PowerPoint版本为2016或2019
set version=16
goto office_new

:office_null
@echo    抱歉,您未安装PowerPoint,或版本不支持
goto ending

:office_old
set dpiMAX=307
goto setDPI

:office_new
set dpiMAX=1000
goto setDPI

:setDPI
@echo     可以进行输出图像分辨率设置
@echo --------------------------------------------
@del temp_setdpi.txt
@echo.
@echo 请输入您想要设置的DPI值 (直接回车设为300)
@echo 取值范围[50~%dpiMAX%]
: inputDPI
@set /p DPI=

@if "%DPI%"=="" @set DPI=300

@echo %DPI%|findstr "[^0-9]" >nul&&(
       echo 输入有误,请输入纯数字
       goto inputDPI)

@if %DPI% GEQ %dpiMAX% @set DPI=%dpiMAX% 
@if %DPI% LEQ 50 @set DPI=50

@echo.
@echo 正在设置DPI为: %DPI% 

reg add HKCU\Software\Microsoft\Office\%version%.0\PowerPoint\Options /v "ExportBitmapResolution" /t "REG_DWORD" /d %DPI% /f

:ending
@echo.
@echo --------------------------------------------
@echo 按任意键退出 & pause>nul